怎么用vbs实现本地连接禁用或启用-创新互联

这篇文章主要介绍“怎么用vbs实现本地连接禁用或启用”，在日常操作中，相信很多人在怎么用vbs实现本地连接禁用或启用问题上存在疑惑，小编查阅了各式资料，整理出简单好用的操作方法，希望对大家解答”怎么用vbs实现本地连接禁用或启用”的疑惑有所帮助！接下来，请跟着小编一起来学习吧！

创新互联公司是一家专业提供威县企业网站建设,专注与网站制作、成都网站建设、H5页面制作、小程序制作等业务。10年已为威县众多企业、政府机构等服务。创新互联专业网站设计公司优惠进行中。

复制代码 代码如下:

Const ssfCONTROLS = 3 

sConnectionName = "本地连接"  '可改成需要控制的连接名称，如"无线网络连接"等 

sEnableVerb = "启用(&A)" 
sDisableVerb = "禁用(&B)"   'XP系统中应为 "停用(&B)" 

set shellApp = createobject("shell.application") 
set oControlPanel = shellApp.Namespace(ssfCONTROLS) 

set oNetConnections = nothing 
for each folderitem in oControlPanel.items 
 if folderitem.name  = "网络连接" then 
   set oNetConnections = folderitem.getfolder: exit for 
 end if 
next 

if oNetConnections is nothing then 
 msgbox "未找到网络连接文件夹" 
 wscript.quit 
end if 

set oLanConnection = nothing 
for each folderitem in oNetConnections.items 
 if lcase(folderitem.name)  = lcase(sConnectionName) then 
   set oLanConnection = folderitem: exit for 
 end if 
next 

if oLanConnection is nothing then 
 msgbox "未找到 '" & sConnectionName & "' item" 
 wscript.quit 
end if 

bEnabled = true 
set oEnableVerb = nothing 
set oDisableVerb = nothing 
s = "Verbs: " & vbcrlf 
for each verb in oLanConnection.verbs 
 s = s & vbcrlf & verb.name 
 if verb.name = sEnableVerb then  
   set oEnableVerb = verb   
   bEnabled = false 
 end if 
 if verb.name = sDisableVerb then  
   set oDisableVerb = verb   
 end if 
next 

'debugging displays left just in case... 
' 
'msgbox s ': wscript.quit 
'msgbox "Enabled: " & bEnabled ': wscript.quit 

'not sure why, but invokeverb always seemed to work  
'for enable but not disable.   
' 
'saving a reference to the appropriate verb object  
'and calling the DoIt method always seems to work. 
' 
if bEnabled then 
'  oLanConnection.invokeverb sDisableVerb 
 oDisableVerb.DoIt 
else 
'  oLanConnection.invokeverb sEnableVerb 
 oEnableVerb.DoIt 
end if 

'adjust the sleep duration below as needed... 
' 
'if you let the oLanConnection go out of scope 
'and be destroyed too soon, the action of the verb 
'may not take... 
' 
wscript.sleep 400

到此，关于“怎么用vbs实现本地连接禁用或启用”的学习就结束了，希望能够解决大家的疑惑。理论与实践的搭配能更好的帮助大家学习，快去试试吧！若想继续学习更多相关知识，请继续关注创新互联网站，小编会继续努力为大家带来更多实用的文章！

当前文章：怎么用vbs实现本地连接禁用或启用-创新互联
本文来源：http://shouzuofang.com/article/ccgpog.html