以太坊众筹智能合约怎么实现

本篇内容主要讲解“以太坊众筹智能合约怎么实现”，感兴趣的朋友不妨来看看。本文介绍的方法操作简单快捷，实用性强。下面就让小编来带大家学习“以太坊众筹智能合约怎么实现”吧!

专注于为中小企业提供网站建设、成都做网站服务,电脑端+手机端+微信端的三站合一,更高效的管理,为中小企业任县免费做网站提供优质的服务。我们立足成都，凝聚了一批互联网行业人才，有力地推动了成百上千家企业的稳健成长，帮助中小企业通过网站建设实现规模扩充和转变。

实现一个好的idea常常需要付出巨大的努力，并且需要大量的资金。我们可以寻求用户捐赠，或者寻求投资机构投资，但这往往很难。对于捐赠，国内的风气不太好，资金去向往往不了了之，捐赠者对于当前的捐赠形式早已失去了信心。而风险投资，对于没有人脉的创业者来说，非常困难。区块链提供了一种众筹的新形式——众筹智能合约。募资人通过众筹合约设定好众筹目标，以及完成时间，设定不同众筹结果所对应的操作（例如目标失败退回全款、目标成功时受益人获得加密代币或ETH）。由于区块链不可篡改的特性，众筹合约会是一个非常吻合的应用场景。

代币和分布自治组织

这个例子中我们将通过解决两个重要的问题进行更好的众筹：

如何管理资金，保证流动性；
筹集资金后如何花钱。

区块链出现之前的众筹项目一般缺少流动性，投资人一旦错过众筹截止时间将无法参与众筹；一旦参与众筹，投资人也不能中途退出。智能合约通过发行代币的形式来记录投资额，并提供了类似股票市场的流动性。投资人可以选择交易或者继续持有。项目成功后投资者可以使用代币交换实物或者产品服务。项目失败的话投资者可以按照原先的约定退出，并且继续持有代币以表纪念。

同样，当前众筹项目也存在资金去向不明的问题。在这个项目中，我们使用DAO（分布式自治组织）记录每一笔资金去向。

合约代码

先放上代码，然后再一步步解读。

pragma solidity ^0.4.16;
interface token {
    function transfer(address receiver, uint amount);
}

contract Crowdsale {
    address public beneficiary;
    uint public fundingGoal; 
    uint public amountRaised; 
    uint public deadline; 
    uint public price;
    token public tokenReward;
    mapping(address => uint256) public balanceOf;
    bool fundingGoalReached = false; 
    bool crowdsaleClosed = false; 
    event GoalReached(address recipient, uint totalAmountRaised); 
    event FundTransfer(address backer, uint amount, bool isContribution); 
    /**
     * Constrctor function
     *
     * Setup the owner
     */
    function Crowdsale(
        address ifSuccessfulSendTo, 
        uint fundingGoalInEthers,        
        uint durationInMinutes,        
        uint etherCostOfEachToken,
        address addressOfTokenUsedAsReward    
    ) {
        beneficiary = ifSuccessfulSendTo;
        fundingGoal = fundingGoalInEthers * 1 ether;
        deadline = now + durationInMinutes * 1 minutes;
        price = etherCostOfEachToken * 1 ether;
        tokenReward = token(addressOfTokenUsedAsReward);
    }
    /**
     * Fallback function
     *
     * The function without name is the default function that is called whenever anyone sends funds to a contract
     */
    function () payable {
        require(!crowdsaleClosed); 
        uint amount = msg.value;
        balanceOf[msg.sender] += amount;
        amountRaised += amount;
        tokenReward.transfer(msg.sender, amount / price);
        FundTransfer(msg.sender, amount, true);
    }
    modifier afterDeadline() {
        if (now >= deadline) _; 
    }
    /**
     * Check if goal was reached
     *
     * Checks if the goal or time limit has been reached and ends the campaign
     */
    function checkGoalReached() afterDeadline { 
       if (amountRaised >= fundingGoal){
            fundingGoalReached = true;
            GoalReached(beneficiary, amountRaised);
        }
        crowdsaleClosed = true;
    }
    /**
     * Withdraw the funds
     *
     * Checks to see if goal or time limit has been reached, and if so, and the funding goal was reached,
     * sends the entire amount to the beneficiary. If goal was not reached, each contributor can withdraw
     * the amount they contributed.
     */
    function safeWithdrawal() afterDeadline { 
       if (!fundingGoalReached) { 
            uint amount = balanceOf[msg.sender];
            balanceOf[msg.sender] = 0; 
           if (amount > 0) { 
               if (msg.sender.send(amount)) {
                    FundTransfer(msg.sender, amount, false);
                } else {
                    balanceOf[msg.sender] = amount;
                }
            }
        } 
        if (fundingGoalReached && beneficiary == msg.sender) { 
            if (beneficiary.send(amountRaised)) {
                FundTransfer(beneficiary, amountRaised, false);
            } else { 
                //If we fail to send the funds to beneficiary, unlock funders balance
                fundingGoalReached = false;
            }
        }
    }
}

构造函数中

fundingGoal = fundingGoalInEthers * 1 ether;
deadline = now + durationInMinutes * 1 minutes;

ether和minutes是以太坊预留的关键字，1 ether == 1000 finney ， 2 days == 48 hours。日期类型的关键字有seconds，minutes，hours， days，weeks，years，以太币单位预留的关键字有wei，finney，szabo，ether。1 finney == 1000 szabo，1 szabo == 10^12 wei。now也是以太坊预留的关键字，代表当前时间。

接下来我们实例化了一个合约：

tokenReward = token(addressOfTokenUsedAsReward);
token的定义在代码开头：

interface token { 
    function transfer(address receiver, uint amount){  }
}

这里我们并未实现token合约，只是告诉编译器我们的token是一个合约，具有一个transfer()函数,并且在给定的地址上有这个合约。

接下来我们看看合约如何接收资金，相关代码如下：

function () {    
    require(!crowdsaleClosed);
    uint amount = msg.value;
    // ...

这个函数很特别，它没有名字，在solidity中我们称之为回退函数（Fallback function），回退函数没有参数，也没有返回值。如果合约接收ether，则必须明确定义回退函数，否则会触发异常，并返回ether。接收ether的函数必须带有关键字payable，否则会报错。

require语句先判断众筹是否结束，如果众筹已经结束，钱将退回给主叫方，避免主叫方出现不必要的损失。

部署通过之后可以用自己的测试账户向合约地址转账，这样就可以参与众筹了。

众筹成功后，如果继续往合约地址转账，钱将会退回你的账户。

到此，相信大家对“以太坊众筹智能合约怎么实现”有了更深的了解，不妨来实际操作一番吧！这里是创新互联网站，更多相关内容可以进入相关频道进行查询，关注我们，继续学习！

文章标题：以太坊众筹智能合约怎么实现
本文链接：http://shouzuofang.com/article/jcpdip.html

网站建设知识

以太坊众筹智能合约怎么实现

代币和分布自治组织

合约代码

其他资讯